欧美极品高清xxxxhd,国产日产欧美最新,无码AV国产东京热AV无码,国产精品人与动性XXX,国产传媒亚洲综合一区二区,四库影院永久国产精品,毛片免费免费高清视频,福利所导航夜趣136

標(biāo)題: 可預(yù)置的24小時(shí)3路時(shí)間控制器 [打印本頁]
作者: wanjung    時(shí)間: 2016-3-21 11:41
標(biāo)題: 可預(yù)置的24小時(shí)3路時(shí)間控制器
  1.         org 0000h
  2.         ajmp main
  3.         org 000bh
  4.         ajmp t100ms
  5.         org 001bh
  6.         ajmp tt1
  7. tt1:    mov th1,#26h       ;定時(shí)器T1中斷程序
  8.          mov tl1,#0fch
  9.          inc 5ah
  10.          mov a,#02h
  11.          cjne a,3ah,ttk
  12.          cpl f0
  13.          mov 5ah,#00h
  14. ttk:     reti
  15. t100ms:        MOV TL0,#0b0H      ;定時(shí)器T0中斷程序
  16.         MOV TH0,#03CH
  17.         PUSH PSW;
  18.         PUSH ACC
  19.         SETB RS0;        工作在1區(qū)
  20.         MOV A,68H
  21.         INC A
  22.         MOV 68H,A       ;
  23.         CJNE A,#0AH,DONE       ;不到1秒，退出中斷
  24.         MOV 68H,#00H           ;1秒，置68H為0
  25.         MOV A,67H;
  26.         INC A            ;秒加一
  27.         MOV 67H,A
  28.         CJNE A,#0AH,DONE;不到十秒，退出
  29.         MOV 67H,#00H    ;到十秒，秒個(gè)位清零，秒十位加一
  30.         MOV A,66H;
  31.         INC A
  32.         MOV 66h,A;
  33.         CJNE A,#06H,DONE;秒十位為6嗎？不，退出
  34.         MOV 66H,#00H;    為6，秒清零，分個(gè)位加一
  35.         MOV A,65H;
  36.         INC A
  37.         MOV 65H,A
  38.         CJNE A,#0AH,DONE  ;分個(gè)位為十嗎？不，退出
  39.         MOV 65H,#00H      ;是，分個(gè)位清零，分十位加一
  40.         MOV A,64H;        分十位
  41.         INC A
  42.         MOV 64H,A
  43.         CJNE A,#06H,DONE   ;分十位為6嗎？不，退出
  44.         MOV 64H,#00H       ;是，分清零，時(shí)個(gè)位加一
  45.         MOV A,63H;        時(shí)個(gè)位
  46.         INC A
  47.         MOV 63H,A
  48.         CJNE A, #04H,DONET0  ;時(shí)個(gè)位為4嗎？不，轉(zhuǎn)DONET0
  49.         MOV A,62H
  50.         CJNE A,#02H,DONE;        是24小時(shí)了嗎？
  51.         MOV 62H,#00H;
  52.         MOV 63H,#00H;                是24小時(shí)了，清零
  53. DONE:        POP Acc                  ; T100ms中斷退出
  54.         POP PSW
  55.         RETI
  56. DONET0:        CJNE A,#0AH,DONE
  57.         MOV 63H,#00H;
  58.         MOV A,62H
  59.         INC A
  60.         MOV 62H,A
  61.         LJMP DONE
  62. MAIN:        MOV A,#0F0H
  63.         MOV P2,A
  64.         MOV SP,#30H

  66.         MOV 6CH,#10H        ;第一開機(jī)時(shí)間標(biāo)志為“10”
  67.         MOV 6FH,#1fH        ;第一關(guān)機(jī)時(shí)間標(biāo)志為“1F”
  68.         MOV 72H,#20H
  69.         MOV 75H,#2fH
  70.         MOV 78H,#30H
  71.         MOV 7BH,#3fH
  72.         setb et1
  73.         SETB ET0        ;T0中斷開
  74.         SETB PT0        ;T0為高優(yōu)先級(jí)中斷
  75.         SETB EA
  76.         SETB F0
  77.         MOV TMOD,#01H        ;T0為方式1、定時(shí)功能
  78.         MOV TL0,#0B0H
  79.         MOV TH0,#3CH        ;定時(shí)初值100ms
  80.         SETB TR0        ;開定時(shí)器
  81. MAIN1:  CLR TR1
  82.         mov 4bh,#00h          ;鍵碼清零
  83.         mov 4ch,#00h          ;AN1鍵序清零
  84.         mov 4dh,#00h          ;AN2鍵序清零
  85.         ACALL DISZH
  86.         ACALL DISP        ;調(diào)顯示子程序
  87. TSHIBI:        MOV A,62H        ;62H為時(shí)十位
  88.         SWAP A
  89.         ORL A,63H        ;63H為時(shí)個(gè)位
  90.         MOV 25H,A        ;25H為小時(shí)
  91.         MOV A,64H        ;64H為分十位
  92.         SWAP A
  93.         ORL A,65H        ;65H為分個(gè)位
  94.         MOV 26H,A        ;26H為分鐘

  96.         MOV A,66H
  97.         SWAP A
  98.         ORL A,67H
  99.         MOV A,27H      ;27H為秒
  100.         JB P3.0,KK0    ;K1斷開，轉(zhuǎn)KK0
  101.         MOV A,#02H     ;手動(dòng)程序
  102.         CJNE A,4BH,DKK1
  103.         ACALL KEYW
  104.         CPL P2.1
  105. DKK1:   MOV A,#03H
  106.         CJNE A,4BH,DKK2
  107.         ACALL KEYW
  108.         CPL P2.2
  109. DKK2:   MOV A,#04H
  110.         CJNE A,4BH,KKK
  111.         ACALL KEYW
  112.         CPL P2.3
  113.         AJMP KKK
  114. KK0:    JNB 0FH,KK2     ;第一路開/關(guān)機(jī)功能關(guān)，轉(zhuǎn)KK2
  115.         MOV A,25H;
  116.         CJNE A,6AH,KK1;        第一路開機(jī)小時(shí)到了嗎？不到，轉(zhuǎn)KK1
  117.         MOV A,26H;        到了，比較分鐘
  118.         CJNE A,6BH,KK1;        分鐘到了嗎？不到，轉(zhuǎn)KK1

  120.         SETB 00H;        開機(jī)時(shí)間到，令00H=1
  121.         SETB P2.1;        第一路輸出開
  122. KK1:    MOV A,25H
  123.         CJNE A,6DH,KK2;        第一路關(guān)機(jī)小時(shí)到了嗎？不到，轉(zhuǎn)KK2
  124.         MOV A,26H;        到了，比較分鐘
  125.         CJNE A,6EH,KK2;        分鐘到了嗎？不到，轉(zhuǎn)KK2

  127.         CLR 00H;        第一路關(guān)機(jī)時(shí)間到，令00H=0
  128.         CLR P2.1;        第一路輸出關(guān)

  130. KK2:    JNB 17H,KK4      ;第二路開/關(guān)機(jī)功能關(guān)，轉(zhuǎn)KK4
  131.         MOV A,25H
  132.         CJNE A,70H,KK3
  133.         MOV A,26H
  134.         CJNE A,71H,KK3

  136.         SETB 00H       
  137.         SETB P2.2       
  138. KK3:        MOV A,25H
  139.         CJNE A,73H,KK4
  140.         MOV A,26H
  141.         CJNE A,74H,KK4

  143.         CLR 00H       
  144.         CLR P2.2

  146. KK4:    JNB 1FH,KKK     ;第三路開/關(guān)機(jī)功能關(guān)，轉(zhuǎn)KKK
  147.         MOV A,25H
  148.         CJNE A,76H,KK5
  149.         MOV A,26H
  150.         CJNE A,77H,KK5

  152.         SETB 00H
  153.         SETB P2.3
  154. KK5:        MOV A,25H
  155.         CJNE A,79H,KKK
  156.         MOV A,26H
  157.         CJNE A,7AH,KKK

  159.         CLR P2.3
  160.         CLR 00H
  161. KKK:        ACALL DISZH
  162.         ACALL DISP
  163.         MOv A,#01H
  164.         CJNE A,4BH,KKK1
  165.         LCALL KEYW
  166.         INC 4CH                ;AN1鍵第一次被按下，AN1鍵序加一
  167.         AJMP MAIN2
  168. KKK1:   AJMP MAIN1
  169. MAIN2:  SETB TR1        ;開定時(shí)器1
  170.         MOV 4DH,#01H        ;AN2鍵序置1
  171. MAIN2A:  ACALL DISZH
  172.         ACALL DISP
  173.         MOV A,#01H
  174.         CJNE A,4BH,DX0        ;AN1鍵第二次被按下嗎？沒有，轉(zhuǎn)DX0
  175.         LCALL KEYW                ;AN1鍵第二次被按下，AN1鍵序加一
  176.         INC 4CH
  177.         AJMP MAIN3
  178. dx0:     mov a,#02h
  179.          cjne a,4bh,set1
  180.          lcall keyw             ;AN2鍵被按下
  181.          inc 4dh                ;AN2鍵序加1
  182.          mov a,#07h
  183.          cjne a,4dh,set1
  184.          mov 4dh,#01h
  185. set1:    acall dset
  186.         ACALL DISZH2
  187.         ACALL DISZH
  188.         ACALL DISP
  189.         MOV A,#05H
  190.         CJNE A,4BH,DDD        ;AN5鍵被按下？否
  191.         LCALL KEYW
  192.         LJMP MAIN1                ;AN5鍵被按下？是，轉(zhuǎn)MAIN1
  193. DDD:    ajmp main2a
  194. MAIN3:  MOV 4DH,#03H    ;開關(guān)機(jī)時(shí)間設(shè)定程序
  195. DDK:    MOV R0,#6AH;
  196. A2:        MOV A,@R0;
  197.         ANL A,#0FH;
  198.         MOV 53H,A;        顯存，53H為時(shí)個(gè)位
  199.         MOV A,@R0
  200.         ANL A,#0F0H
  201.         SWAP A
  202.         MOV 52H,A;        顯存，52H為時(shí)十位
  203.         INC R0;
  204.         MOV A,@R0;
  205.         ANL A,#0FH;
  206.         MOV 55H,A;        顯存，55H為分個(gè)位
  207.         MOV A,@R0;
  208.         ANL A,#0F0H;
  209.         SWAP A;
  210.         MOV 54H,A;        顯存，54H為分十位
  211.         INC R0
  212.         MOV A,@R0;
  213.         ANL A,#0FH;
  214.         MOV 57H,A;        顯存，
  215.         MOV A,@R0;
  216.         ANL A,#0F0H;
  217.         SWAP A;
  218.         MOV 56H,A;        顯存，56H、57H在顯示時(shí)間時(shí)為秒數(shù)值在設(shè)置時(shí)為開關(guān)機(jī)標(biāo)志
  219.         DEC R0
  220.         DEC R0
  221. A3:
  222.         ACALL DISP
  223.         MOV A,#01H
  224.         CJNE A,4BH,DKX0               ;AN1鍵又一次被按下嗎？沒有，轉(zhuǎn)DKX0
  225.         LCALL KEYW                ;AN1鍵又一次被按下，AN1鍵序加一
  226.         INC 4CH
  227.         mov a,4ch
  228.         CJNE a,#08H,DDD1
  229.         MOV 4CH,#02H
  230.         ajmp main3
  231. DDD1:        INC R0
  232.         INC R0
  233.         inc r0
  234.         mov 4dh,#03h
  235.         AJMP A2
  236. dKx0:     mov a,#02h
  237.          cjne a,4bh,setK1
  238.          lcall keyw             ;AN2鍵被按下
  239.          inc 4dh                ;AN2鍵序加1
  240.          mov a,#07h
  241.          cjne a,4dh,setK1
  242.          mov 4dh,#03h
  243. setK1:  MOV A,#04H               ;AN4鍵被按下嗎？
  244.         CJNE A,4BH,SETK2
  245.         lcall keyw               ;AN4鍵被按下
  246.         MOV A,4CH
  247.         CJNE A,#02H,DXD1
  248.         CPL 0FH
  249. DXD1:   CJNE A,#04H,DXD2
  250.         CPL 17H
  251. DXD2:   CJNE A,#06H,SETK2
  252.         CPL 1FH
  253. SETK2:  acall dset
  254.         ACALL DISZH3
  255.         ACALL DISP
  256.         MOV A,#05H
  257.         CJNE A,4BH,DDD3               ;AN5鍵被按下？否
  258.         LCALL KEYW

  260.         LJMP MAIN1                ;AN5鍵被按下？是，轉(zhuǎn)MAIN1
  261. DDD3:   AJMP A2

  263. diSP:                                 ;顯示子程序
  264.          mov dptr,#tab
  265.          mov a,57h                  ;顯示秒個(gè)位
  266.          mov r3,4dh
  267.          cjne r3,#01h,dd1           
  268. dk1:     jb F0,DD1                  
  269.          mov a,#0ffh                ;F0為0，該位不顯示,以達(dá)到該位閃爍效果
  270.          sjmp dd2
  271. dd1:     movc a,@a+dptr
  272. dd2:         mov p1,a                 ;送段碼
  273.          clr p0.0                 ;開秒個(gè)位

  275. dsp1:         acall dll
  276. d1:         setb p0.0                ;關(guān)個(gè)位
  277.          mov a,56h                ;顯示左起第5位（秒十位）
  278.          mov r3,4dh
  279.          cjne r3,#02h,dd3
  280. dk2:     jb F0,DD3
  281.          mov a,#0ffh
  282.          sjmp dd4
  283. dd3:     movc a,@a+dptr
  284. dd4:     MOV B,A
  285.          MOV A,4CH
  286.          CJNE A,#02H,DXD3
  287.          MOV A,B
  288.          CPL A
  289.          ORL A,21H
  290.          CPL A                    ;判斷是否顯示第一次開關(guān)機(jī)標(biāo)志中的小數(shù)點(diǎn)
  291.          AJMP ZX
  292. DXD3:    CJNE A,#04H,DXD4
  293.          MOV A,B
  294.          CPL A
  295.          ORL A,22H
  296.          CPL A                    ;判斷是否顯示第二次開關(guān)機(jī)標(biāo)志中的小數(shù)點(diǎn)
  297.          AJMP ZX
  298. DXD4:    CJNE A,#06H,DXD5
  299.          MOV A,B
  300.          CPL A
  301.          ORL A,23H
  302.          CPL A                    ;判斷是否顯示第三次開關(guān)機(jī)標(biāo)志中的小數(shù)點(diǎn)
  303.          AJMP ZX
  304. DXD5:    MOV A,B
  305. ZX:      mov p1,a
  306.          clr p0.1
  307.          jb p0.7,dsp2             ;AN5鍵沒有按下，轉(zhuǎn)dsp2
  308.          acall del1
  309.          jb p0.7,dsp2
  310.          ajmp key5                ;AN5鍵按下，轉(zhuǎn)key5鍵碼識(shí)別
  311. dsp2:         acall dll
  312. d2:         setb p0.1
  313.          mov a,55h                ;顯示分個(gè)位
  314.          mov r3,4dh
  315.          cjne r3,#03h,dd5         ;AN3鍵序?yàn)?嗎？

  317. dk3:     jb F0,DD5                ;F0為1，顯示
  318.          mov a,#0ffh
  319.          sjmp dd6
  320. dd5:         movc a,@a+dptr
  321. dd6:         mov p1,a
  322.          clr p0.2
  323.          jb p0.7,dsp3
  324.          acall del1
  325.          jb p0.7,dsp3
  326.          ajmp key4               ;AN4鍵按下，轉(zhuǎn)key4鍵碼識(shí)別
  327. dsp3:         acall dll
  328. d3:         setb p0.2
  329.          mov a,54h
  330.          mov r3,4dh
  331.          Cjne r3,#04h,dd7
  332. dk4:     jb F0,DD7
  333.          mov a,#0ffh
  334.          sjmp dd8
  335. dd7:     movc a,@a+dptr
  336. dd8:         mov p1,a
  337.          clr p0.3
  338.          jb p0.7,dsp4
  339.          acall del1
  340.          jnb p0.7,key3          ;AN3鍵按下，轉(zhuǎn)key3鍵碼識(shí)別
  341. dsp4:         acall dll
  342. d4:         setb p0.3
  343.          mov a,53h
  344.          mov r3,4dh
  345.          cjne r3,#05h,dd9
  346. dk5:     jb F0,DD9
  347.          mov a,#0ffh
  348.          sjmp dd10
  349. dd9:         movc a,@a+dptr
  350. DD10:   MOV P1,A

  352.          clr p0.4
  353.          jb p0.7,dsp5
  354.          acall del1
  355.          jnb p0.7,key2          ;AN2鍵按下，轉(zhuǎn)key2鍵碼識(shí)別
  356. dsp5:   acall dll
  357. d5:     setb p0.4
  358.          mov a,52h
  359.          mov r3,4dh
  360.          cjne r3,#06h,dd11
  361. dk6:     jb F0,DD11
  362.          mov a,#0ffh
  363.          sjmp dd12
  364. dd11:         movc a,@a+dptr
  365. dd12:         mov p1,a

  367.          clr p0.5
  368.          jb p0.7,dsp6
  369.          acall del1
  370.          jnb p0.7,key1          ;AN1鍵按下，轉(zhuǎn)key1鍵碼識(shí)別
  371. dsp6:    acall dll
  372. d6:      setb p0.5
  373.          ret
  374. tab:    DB        0C0H                ; 0
  375.         DB        0F9H                ; 1
  376.         DB        0A4H                ; 2
  377.         DB        0B0H                ; 3
  378.         DB        099H                ; 4
  379.         DB        092H                ; 5
  380.         DB        082H                ; 6
  381.         DB        0F8H                ; 7
  382.         DB        080H                ; 8
  383.         DB        090H                ; 9
  384.         DB        088H                ; A
  385.         DB        083H                ; B
  386.         DB        0C6H                ; C
  387.         DB        0A1H                ; D
  388.         DB        086H                ; E
  389.         DB        08EH                ; F
  390. key1:    mov 4bh,#01h           ;保存AN1鍵碼
  391.          ajmp d6
  392. key2:    mov 4bh,#02h
  393.          ajmp d5
  394. key3:    mov 4bh,#03h
  395.          ajmp d4
  396. key4:    mov 4bh,#04h
  397.          ajmp d3
  398. key5:    mov 4bh,#05h
  399.          ajmp d2
  400. keyw:    mov 4bh,#00h             ;鍵等待釋放程序
  401.          lcall disp
  402.          mov a,4bh
  403.          jnz keyw
  404.          lcall disp
  405.          mov a,4bh
  406.          jnz keyw
  407.          ret
  408. DISZH:   MOV 52H,62H         ;時(shí)間值送顯存子程序
  409.         MOV 53H,63H
  410.         MOV 54H,64H
  411.         MOV 55H,65H
  412.         MOV 56H,66H
  413.         MOV 57H,67H
  414.         RET
  415. DISZH2: MOV 62H,52H          ;正常時(shí)間設(shè)置數(shù)據(jù)裝入子程序
  416.         MOV 63H,53H
  417.         MOV 64H,54H
  418.         MOV 65H,55H
  419.         MOV 66H,56H
  420.         MOV 67H,57H
  421.         RET
  422. DISZH3: MOV A,52H             ;開關(guān)機(jī)時(shí)間設(shè)置數(shù)據(jù)裝入子程序
  423.         SWAP A
  424.         ORL A,53H
  425.         MOV @r0,a
  426.         INC R0
  427.         MOV A,54H
  428.         SWAP A
  429.         ORL A,55H
  430.         MOV @R0,A
  431.         dec r0
  432.         RET
  433. dset:    mov r3,4dh                ;設(shè)定子程序
  434.          cjne r3,#01h,dx2          ;AN2鍵序不為1，轉(zhuǎn)DX2
  435.          mov r4,4bh
  436.          cjne r4,#03h,dx11         ;AN2鍵序?yàn)?，但AN3鍵未被按下
  437.          lcall keyw                ;AN2鍵被按下，等待鍵釋放
  438.          inc 57h                   ;秒個(gè)位的數(shù)值被更改（加1）
  439.          mov r5,57h
  440.          cjne r5,#0ah,dx11         
  441.          mov 57h,#00h
  442. dx11:         ajmp dx
  443. dx2:     mov r3,4dh
  444.          cjne r3,#02h,dx3
  445.          mov r4,4bh
  446.          cjne r4,#03h,dx12
  447.          lcall keyw
  448.          inc 56h
  449.          mov r5,56h
  450.          cjne r5,#07h,dx12         ;使該位（秒十位）的數(shù)值可在0--6之間隨意設(shè)定
  451.          mov 56h,#00h
  452. dx12:         ajmp dx
  453. dx3:     cjne r3,#03h,dx4
  454.          mov r4,4bh
  455.          cjne r4,#03h,dx13
  456.          lcall keyw
  457.          inc 55h
  458.          mov r5,55h
  459.          cjne r5,#0ah,dx13         
  460.          mov 55h,#00h
  461. dx13:         ajmp dx
  462. dx4:     cjne r3,#04h,dx5
  463.          mov r4,4bh
  464.          cjne r4,#03h,dx14
  465.          lcall keyw
  466.          inc 54h
  467.          mov r5,54h
  468.          cjne r5,#07h,dx14           ;使該位（分十位）的數(shù)值可在0--6之間隨意設(shè)定
  469.          mov 54h,#00h
  470. dx14:         ajmp dx
  471. dx5:     cjne r3,#05h,dx6
  472.          mov r4,4bh
  473.          cjne r4,#03h,dx15
  474.          lcall keyw
  475.          inc 53h                ;時(shí)個(gè)位的數(shù)值被更改（加1）
  476.         MOV A,52H
  477.         SWAP A
  478.         ORL A,53H
  479.         CLR C
  480.         CJNE A,#24H,DXD6
  481.         AJMP DXD7
  482. DXD6:   JC DXD7
  483.         mov 53h,#00h                ;時(shí)數(shù)大于24，置時(shí)個(gè)位為零
  484. DXD7:   mov r5,53h
  485.          cjne r5,#0ah,dx15        ;在時(shí)鐘數(shù)不大于24的前提下，使該位（時(shí)個(gè)位）的數(shù)值可在0--9之間隨意設(shè)定
  486.          mov 53h,#00h
  487. dx15:         ajmp dx
  488. dx6:     cjne r3,#06h,dx
  489.          mov r4,4bh
  490.          cjne r4,#03h,dx16
  491.          lcall keyw                ;AN3按下并釋放，時(shí)十位加一

  493.          inc 52h
  494.         MOV A,52H
  495.         SWAP A
  496.         ORL A,53H
  497.         CLR C
  498.         CJNE A,#24H,DX7
  499.         AJMP DX8
  500. DX7:    JC DX8
  501.         MOV 52H,#00H                ;時(shí)數(shù)大于24，置時(shí)十位為零
  502. DX8:    mov r5,52h
  503.          cjne r5,#03h,dx16        ;在時(shí)鐘數(shù)不大于24的前提下，使該位（時(shí)十位）的數(shù)值可在0--2之間隨意設(shè)定
  504.          mov 52h,#00h
  505. dx16:         ajmp dx
  506. dx:         acall disp    ;調(diào)用顯示子程序
  507.          ret
  508. dll:     MOV R7,#01fH
  509. DL1:     MOV R6,#1fH
  510. DL2:     DJNZ R6,DL2
  511.          DJNZ R7,DL1
  512.          RET
  513. DEL1:    MOV R7,#0aH
  514. DEL1A:   MOV R6,#2eH
  515. DEL1B:   DJNZ R6,DEL1B
  516.          DJNZ R7,DEL1A
  517.          RET
  518.          END
復(fù)制代碼


Schematic Prints.jpg (117.22 KB, 下載次數(shù): 229)

Schematic Prints.jpg

3路輸出時(shí)間控制器源程序.zip

1.16 KB, 下載次數(shù): 55, 下載積分: 黑幣 -5

源程序
作者: leileiq910    時(shí)間: 2016-3-21 15:36
謝謝分享，拿走學(xué)習(xí)去了。
作者: wbwcf13e    時(shí)間: 2019-2-20 23:50
這個(gè)電路在2006年《電子報(bào)》上發(fā)表過，我按照上面的程序試驗(yàn)一下，不能設(shè)置和走時(shí)，不知道是怎么回事？望解！
作者: rayin    時(shí)間: 2020-11-15 14:11
強(qiáng)，全匯編



歡迎光臨 (http://www.raoushi.com/bbs/) Powered by Discuz! X3.1